--- Computations for comparing degenerations of Gr(3,6) from plabic graphs with
--- the tropical Grassmannian Trop Gr(3,6). 
--- Written by Milena Hering, with help from Arend Bayer, Daniel Erman, Claudiu Raicu, Greg Smith. 

needsPackage "Polyhedra"
loadPackage "gfanInterface"

generateInitialIdeals = L -> (
    L1 := apply(L, j -> apply (j, i -> -i + max j));
    II = flatten for i from 0 to #L1-1 list (
	M := {};
    	append(M,initialIdeal(L1#i,I'))
	);
    II
    )

sgn = lis -> (
    rez := 1;
    for i from 0 to #lis-2 do for j from i+1 to #lis-1 do if lis#i > lis#j then rez = rez * (-1);
    rez
    )


sigmaMap = (L,k,d,I) -> (
    f := map(R,R,apply(apply(subsets(k+1,d+1),subs -> apply(subs,i->L#i)), 
    ter -> p_(toSequence sort ter) * sgn(ter)));
    f(I)
    )

permutedIdeals = (k,d,I) -> (
    L := permutations(k+1);
    for i from 0 to #L-1 list sigmaMap(L#i,k,d,I)
    )

-- list of weight vectors obtained from plabic graph in the order of the table in our paper
PlabicGraphVectors = {
    {0,0,1,1,1,1,1,1,1,4,1,1,1,1,1,4,4,4,5,5},
    {0,0,0,3,0,0,3,3,4,4,3,3,4,4,4,4,4,4,4,7},
    {0,0,1,1,0,1,1,2,2,5,3,3,3,3,3,5,3,3,5,6},
    {0,0,0,0,0,0,0,1,1,2,0,0,0,1,1,2,2,2,3,5},
    {0,0,2,3,1,2,3,2,3,6,4,4,4,4,4,6,5,5,6,6},
    {0,0,1,2,0,1,2,2,3,5,4,4,4,4,4,5,4,4,5,6},
    {0,0,0,0,0,0,0,2,2,3,1,1,1,2,2,3,2,2,3,6},
    {0,0,0,1,0,0,1,2,2,2,0,0,1,2,2,2,3,3,3,6},
    {0,0,0,1,0,0,1,3,3,3,1,1,2,3,3,3,3,3,3,7},
    {0,0,0,3,1,1,3,2,3,3,1,1,3,2,3,3,5,5,5,6},
    {0,0,1,3,2,2,3,2,3,4,2,2,3,2,3,4,6,6,6,6},
    {0,0,1,4,2,2,4,2,4,5,3,3,4,3,4,5,6,6,6,6},
    {0,0,2,2,1,2,2,2,2,6,3,3,3,3,3,6,4,4,6,6},
    {0,0,0,4,1,1,4,2,4,4,2,2,4,3,4,4,5,5,5,6},
    {0,0,0,0,0,0,0,2,2,4,2,2,2,3,3,4,3,3,4,6},
    {0,0,1,3,1,1,3,1,3,5,3,3,4,3,4,5,5,5,5,5},
    {0,0,0,2,0,0,2,2,3,3,0,0,2,2,3,3,4,4,4,6},
    {0,0,0,2,1,1,2,2,2,2,1,1,2,2,2,2,4,4,4,6},
    {0,0,2,4,2,3,4,3,4,6,4,4,4,4,4,6,6,6,7,7},
    {0,0,1,1,0,1,1,2,2,4,2,2,2,2,2,4,2,2,4,6},
    {0,0,1,1,1,1,1,1,1,5,2,2,2,2,2,5,4,4,5,5},
    {0,0,0,0,0,0,0,1,1,3,0,0,0,1,1,3,3,3,4,5},
    {0,0,0,2,0,0,2,3,3,3,2,2,3,3,3,3,3,3,3,7},
    {0,0,0,4,1,1,4,3,4,4,3,3,4,4,4,4,5,5,5,7},
    {0,0,1,2,1,1,2,1,2,4,1,1,2,1,2,4,5,5,5,5},
    {0,0,1,3,0,1,3,3,4,5,4,4,4,4,4,5,4,4,5,7},
    {0,0,1,3,1,2,3,3,3,4,3,3,3,3,3,4,4,4,5,7},
    {0,0,0,1,0,0,1,1,2,4,1,1,2,2,3,4,4,4,4,5},
    {0,0,0,0,0,0,0,1,1,4,1,1,1,2,2,4,3,3,4,5},
    {0,0,1,2,1,1,2,1,2,5,2,2,3,2,3,5,5,5,5,5},
    {0,0,0,1,0,0,1,1,2,3,0,0,1,1,2,3,4,4,4,5},
    {0,0,1,2,0,1,2,3,3,4,3,3,3,3,3,4,3,3,4,7},
    {0,0,0,3,1,1,3,3,3,3,2,2,3,3,3,3,4,4,4,7},
    {0,0,1,4,1,2,4,3,4,5,4,4,4,4,4,5,5,5,6,7}
    }

-- list of weight vectors given in Speyer-Sturmfels in the interior of the 3d cones in Gr(3,6) 
-- in order FFGG EEEE EEFF1 EEFF2 EFFG EEEG EEFG
TropGrassmannian3d={{1, 1, 1, 1, 2, 0, 0, 0, 0, 2, 2, 0, 0, 0, 0, 2, 2, 2, 2, 2},
   {1, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 1, 0},
   {2, 1, 1, 1, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 1, 0, 0, 1, 2},
   {0, 0, 0, 0, 2, 0, 0, 0, 0, 2, 1, 0, 0, 0, 0, 1, 1, 1, 1, 1},
   {1, 1, 1, 1, 1, 0, 0, 0, 0, 3, 1, 0, 0, 0, 0, 2, 1, 1, 1, 1},
   {0, 0, 1, 0, 1, 0, 0, 0, 0, 0, 2, 0, 0, 0, 0, 0, 1, 1, 2, 1},
   {0, 0, 0, 1, 3, 0, 0, 0, 0, 0, 2, 0, 0, 0, 0, 0, 2, 2, 1, 1}}

-- list of weight vectors given in Speyer-Sturmfels in the interior of some 2d cones in trop Gr(3,6)
-- in order EEE,EEF, EEG, EFF, EFG, FFG, FGG
TropGrassmannian2d={{0,0,0,0,0,0,0,0,0,1,0,0,0,1,0,0,0,1,0,0},
   {0,0,1,0,0,0,0,0,0,0,0,1,0,1,0,2,0,1,0,0},
   {1,1,1,1,0,0,1,0,0,0,0,0,2,0,0,0,1,0,0,0},
   {0,0,1,1,0,2,0,1,0,1,0,0,1,0,1,1,0,0,0,0},
   {0,0,1,0,0,1,3,1,0,1,0,0,1,0,0,0,0,1,2,0},
   {1,0,2,0,0,2,0,2,1,2,1,1,1,0,0,0,0,0,0,1},
   {1,1,1,1,0,0,1,2,0,0,0,0,1,2,0,0,2,1,1,2}}


-- list of weight vectors given in Speyer-Sturmfels in the interior of some 1d cones in trop Gr(3,6)
-- in order EE, FF, GG, EF1, EF2, EG, FG
TropGrassmannian1d = {{1,0,0,0,0,0,0,1,0,0,0,0,0,0,0,0,0,0,0,0},
     {1,1,1,1,1,0,0,0,0,0,1,0,0,0,0,0,1,1,0,0},
     {1,1,1,1,1,0,0,0,0,1,1,0,0,0,0,1,1,1,1,1},
     {2,1,1,1,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0},
     {1,0,0,0,0,0,0,1,0,0,0,0,0,1,0,0,1,0,0,1},
     {1,1,1,1,0,0,0,0,0,1,0,0,0,0,0,1,0,0,0,0},
     {2,2,2,2,0,0,0,0,0,1,0,0,0,0,0,1,0,0,0,0}}
 
-- list of weight vectors given in Speyer-Sturmfels that are vertices in trop Gr(3,6)
-- E, F, G
TropGrassmannian0d = {{1,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0},
    {1,1,1,1,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0},
    {1,1,1,1,0,0,0,0,0,1,0,0,0,0,0,1,0,0,0,0}}

-- list of weight vectors given in Speyer-Sturmfels
TropGrassmannian = TropGrassmannian3d|TropGrassmannian2d|TropGrassmannian1d|TropGrassmannian0d

I=Grassmannian(2,5) 
R= QQ**ring(I)
I' = substitute(I,R)  
printWidth = 70

PlabicIdeals = generateInitialIdeals PlabicGraphVectors
TropicalIdeals = generateInitialIdeals TropGrassmannian

equalsTropicalIdeal = I -> (
    for i from 0 to #TropicalIdeals-1 list (
       if (I==TropicalIdeals#i) == true  then return i else continue);
    return -1
   )

end
----------------------------
restart

load "permutations.m2"
k=5
d=2
use R
Permutations=permutations(k+1);

----This computes a list. Each entry is a list of 3 elements. 
----The first one is the index of the plabic graph vector from PlabicGraphVectors, 
----the second one is a permutaion, 
----the third one is the index of a vector from the tropical Grassmannian as in TropGrassmannian. 
----If such a triple is in the list, it means that the initial ideal with respect to the Plabic graph vector
----is equal to the initial ideal with respect to the Tropical Grassmannaian vector after applying the 
----permutation. 
M = {}
for l from 0 to #PlabicIdeals-1 do (
    P=permutedIdeals(k,d,PlabicIdeals#l);    
    for i from 0 to #P-1 do (
          j = equalsTropicalIdeal(P#i);
    	  if (j != -1) then M = append(M, {l,Permutations#i, j}))) 
M